Source code (which I also release under the license given here) runs in w:SuperCollider:

// Written by Dan Stowell, September 2006

b = Buffer.read(s,"sounds/break2.snd"); // Provide a simple breakbeat loop
(
var ampTable = Signal.hanningWindow(1024,100).squared;
var ampBuf = Buffer.loadCollection(s, ampTable);

SynthDef("accelerando_inf1", { arg out=0,bufnum=0;
	var pos, posses, pitches, amps, sons;

	// "pos" is a kind of master pitch control, linear varying between one and zero
	pos = Phasor.ar(1, 0.007 / SampleRate.ir, 0, 1);
	
	posses = (pos + ((0..4)/5)).wrap(0.0, 1.0); // Evenly spaced circularly within 0 to 1
	
 	pitches = (0.2 * 2.0.pow(posses * 5));
	
	amps = BufRd.kr(1, ampBuf.bufnum, posses * BufFrames.ir(ampBuf.bufnum));
	
	sons = (PlayBuf.ar(1, bufnum, pitches.poll(100), loop:1) * amps * 10);
	
	Out.ar(out,
		Pan2.ar(sons.mean.softclip)
	)
}).play(s,[\out, 0, \bufnum, b.bufnum]);
)

Originally published online at http://swiki.hfbk-hamburg.de/MusicTechnology/826

Eu, como posuidor dos dereitos de autor desta obra, pola presente publícoa baixo a seguinte licenza:

Este ficheiro está licenciado baixo a licenza Creative Commons recoñecemento compartir igual 3.0 sen adaptar.

Vostede é libre de:

• compartir – copiar, distribuír e difundir a obra
• facer obras derivadas – adaptar a obra

Baixo as seguintes condicións:

• recoñecemento – Debe indicar a debida atribución de autoría, fornecer unha ligazón á licenza e indicar se se realizaron cambios. Pode facer isto de calquera forma razoable, mais non nunha forma que indique que quen posúe a licenza apoia ou subscribe o seu uso da obra.
• compartir igual – Se altera, transforma ou amplía este contido, debe publicar as súas contribucións baixo a mesma licenza ou outra compatible á orixinal.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue